unittest
 {
     import ddl;
     import std.string : toStringz;
     import core.stdc.stdio; // import the module as usual

     // load the library C to resolve extern(C) functions declared
     // in core.std.stdio, but load no functions yet
     auto stdio = loadLibrary!(core.stdc.stdio)(libraryFilename("c")~".6", false);

     // not loaded yet
     assert(stdio.printf == null);

     // load the function printf
     stdio.loadFunction!("printf")();
     // ... and call it
     stdio.printf(toStringz("Hello World.\n"));
 }

 unittest
 {
     import ddl;
     import deimos.openssl.aes;

     auto aes = loadLibrary!(deimos.openssl.aes)("ssl");
     assert(aes.loadedFunctions == ["AES_options", "AES_set_encrypt_key",
               "AES_set_decrypt_key", "AES_encrypt", "AES_decrypt",
               "AES_ecb_encrypt", "AES_cbc_encrypt", "AES_cfb128_encrypt",
               "AES_cfb1_encrypt", "AES_cfb8_encrypt", "AES_ofb128_encrypt",
               "AES_ctr128_encrypt", "AES_ige_encrypt", "AES_bi_ige_encrypt",
               "AES_wrap_key", "AES_unwrap_key"]);
 }

 import ddl;
 // declare either Library!(deimos.openssl.sha) sha or import deimos.openssl.sha
 version(ddl) mixin declareLibraryAndAlias!("deimos.openssl.sha", "sha");
 else import deimos.openssl.sha;

 unittest
 {
     version(ddl) sha = loadLibrary!(deimos.openssl.sha)("ssl");

     // use as usual
     ubyte[] ibuf = [0x61, 0x62, 0x63];
     ubyte[20] obuf;
     SHA1(ibuf.ptr, ibuf.length, obuf.ptr);

     assert(obuf == [0xA9, 0x99, 0x3E, 0x36, 0x47, 0x06, 0x81, 0x6A, 0xBA,0x3E,
                     0x25, 0x71, 0x78, 0x50, 0xC2, 0x6C, 0x9C, 0xD0, 0xD8, 0x9D]);
 }

 unittest
 {
     import ddl;
     import std.string : toStringz;
     import core.stdc.stdio;

     // throws if some_library could not be loaded
     assertThrown!UnsatisfiedLinkException(loadLibrary!(core.stdc.stdio)("some_library", false));
     auto stdio = loadLibrary!(core.stdc.stdio)(libraryFilename("c")~".6", false);

     // compile error, since foobar is not extern(C) function in core.stdc.stdio
     static assert(!__traits(compiles, stdio.loadFunction!("foobar")()));

     // stdio.printf is not loaded
     assert(stdio.printf == null);
     // calling it results in a segfault
     //stdio.printf(toStringz("Hello World\n"));

     // assuming fun is a extern(C) declared function but not defined
     assertThrown!UnsatisfiedLinkException(stdio.loadFunction!("fun")());
 }